﻿10 clear 
20 :return ;P=50;G=2000;L=500;D=10;S=0;M=0;K=0;X=0;print "WHAT IS YOUR NAME? ",
30 V=KP;TV=V;if V=31X=X-1;goto 30
40 if V#13X=X+1;@(X)=V;goto 30
50 for Y=1to 20;gosub 360;print " I BEG to REPORT to YOU. ON YEAR", #3,Y
60 N=rnd (5)+2;R=rnd (4)div 4mul Gdiv N;if R>0G=G-R;print "RATS ATE ",#1,R," BUSHELS"
70 N=rnd (4)+1;T=rnd (6)div 6mul Gdiv N;if T>0G=G-T;print "THIEVES STOLE ",#1,T," BUSHELS 
80 if rnd (13)div 13=1W=1
90 if W=1E=rnd (6);print "A STRIKE HAS BEEN CALLED BY LOCAL 462 OF THE UNION THEY DEMAND",#2,E," MORE BUSHELS"
100 if W=1input "WHAT IS YOUR OFFER?"O;if E-O<rnd (3)D=D+O;print "FEED YOUR PEOPLE ",#1,D," BUSHELS PER YEAR";W=0
110 N=rnd (30);if N<3print "A PLAGUE HAS HIT THE CITY.   HALF THE PEOPLE DIED";P=Pdiv 2
120 I=Pdiv 5+rnd (30);P=P+I;print "NEW PEOPLE",#4,I;print "PEOPLE STARVED",#4,S;print "POPULATION OF THE CITY ",#1,P
130 print "ACRES OF LAND",#6,L;H=rnd (6);if H=1print "A DROUGHT HAS HIT THE LAND
140 if W=1print "THE UNION PICKETS AND THE GRAIN ROTS";goto 160
150 if M#0print #4,M," ACRES PLANTED";print #4,H," BUSHELS PER ACRE";V=Mmul H;print #4,V," HARVEST FOR THIS YEAR";G=G+V
160 print "BUSHELS OF GRAIN",#6,G;A=rnd (10)+16
170 print "BUY # ACRES @",#4,A;input " BUSHELS PER ACRE?"B;if Bmul A>Ggosub 350;goto 170
180 U=0;if B=0if L#0input "SELL # ACRES?"U;if U>Lgosub 340;goto 180
190 G=G-Amul B+Amul U;L=L+B-U
200 input "BUSHELS to FEED CITY?"C;if C>Ggosub 350;goto 200
210 G=G-C;F=Cdiv D;if F>P F=P
220 if F>Pdiv 2+Pdiv 20goto 270
230 gosub 360;print " YOU HAVE BEEN ACCUSED OF STARVING YOUR PEOPLE";print "A JURY WILL DECIDE YOUR FATE
240 if rnd (4)=1print "THE JURY HAS FOUND YOU NOT GUILTY BY REASON OF INSANITY. BE MORE CAREFUL !!";goto 270
250 print "YOU HAVE BEEN FOUND GUILTYAND ARE SENTENCED to LIFE ON A LONELY ROCK IN THE   SUMERIAN SEA.
260 goto 320
270 S=P-F;K=K+S;P=F;M=0
280 if L#0input "# ACRES to PLANT?"M;if Mmul 3>Ggosub 350;goto 280
290 if M>Pmul 10gosub 330;print #1,P," WORKERS";goto 280
300 if M>Lgosub 340;goto 280
310 G=G-Mmul 3;next Y;gosub 360;print " YOU COMPLETED YOUR TERM, BUT STARVED ",#1,K," PEOPLE
320 A=KP;goto 10
330 print "SORRY YOU ONLY HAVE ",;return
340 gosub 330;print #1,L," ACRES";return
350 gosub 330;print #1,G,"  BUSHELS";return
360 print "KING ",;for N=1to X;TV=@(N);next N;return

